asp - asp.net - aspcode.it

COMMUNITY - Login
 Username:
 
 Password:
 
Voglio registrarmi!
Password dimenticata?
 Utenti on-line: 0
 Ospiti on-line: 7945
ASPCode.it - Store

  > > Tips

Estrarre i titoli degli ultimi post nello YaBB Forum
di Giacomo Graziosi

Data di pubblicazione: 09/07/2002        Voto della community: 0,00 (Votanti: 0)

Questo script permetterà a chi utilizza il forum YaBB di elencare e linkare il titolo dell'ultimo messaggio postato su ogni forum.
Il funzionamento è semplice: vengono letti tutti i file di testo contenuti nella cartella Boards con grandezza superiore a 0 (ogni file di testo corrisponde ad un forum come si potrà notare dal fatto che i nomi dei file corrispondono ai nomi chiave dei forum): questi file contengono i riferimenti ad ogni messaggio postato sui forum. A questo punto sarà sufficiente leggere la prima riga di ogni file ed estrarre l'id ed il titolo relativi al messaggio. Per finire non rimarrà che da costruire il collegamento, che sarà nella forma:
/cgi-bin/YaBB.pl?board=NomeDelForum;action=display;num=IDDelMessaggio
con i dati precedentemente raccolti.

<html>
<head>
</head>
<body>

<%
'Le variabili di cui avremo bisogno.
Dim objFSO, objFile, objFolder, strTemp, objOpenFile, strRead, strMessID, strBoard

'Inizializziamo il FileSystemObject
set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Associamo la cartella contenente i file relativi ai forum alla variabile objFolder.
set objFolder = objFSO.GetFolder(Server.Mappath("/public/yabb/boards/"))
'Eseguiamo un ciclo per processare ogni file nella cartella.
For Each objFile in objFolder.Files
  'Selezioniamo solo i file di testo (estensione .txt) non vuoti (dimensione superiore a 0)
  If objFile.Size > 0 and objFSO.GetExtensionName(objFile.Name) = "txt" then
    'Apriamo il file
    set objOpenFile = objFSO.OpenTextFile(objFile.Path, 1)
    'Leggiamo la prima riga cioè quella relativa all'ultimo post nel forum che stiamo analizzando.
    strTemp = objOpenFile.ReadLine
    'Otteniamo l'id del messaggio prendendo il primo elemento dell'array costruito spezzando con il carattere "|" la riga letta.
    strMessID = Split(strTemp, "|")(0)
    'Otteniamo il titolo del messaggio selezionando il secondo elemento dell'array.
    strRead = Split(strTemp, "|")(1)
    'Chiudiamo il file.
    objOpenFile.Close
    'Otteniamo il nome chiave del forum togliendo ".txt" dal nome del file esaminato.
    strBoard = Replace(objFile.Name, Right(objFile.Name, 4), "")

    'Costruiamo il collegamento e stampiamo il risultato ottenuto.
%>

<font face="Verdana" size="1"><a href="/cgi-bin/YaBB.pl?board=<%=strBoard%>;action=display;num=<%=strMessID%>"><%=strRead%></a></font><br>
<%

  end if
Next

'Liberiamo le risorse
Set objFSO = Nothing
Set objFile = Nothing
Set objFolder = Nothing
Set objOpenFile = Nothing
%>

</body>
</html>




Utenti connessi: 7945