Come utilizzare l'oggetto mail Persits ASPEmail - ASPCode.it - ASP

Come utilizzare l'oggetto mail Persits ASPEmail

Data di pubblicazione: 14/01/2003 Voto della community: 5,00 (Votanti: 1)

PERSITS ASPEmail è un oggetto mail che può essere installato su qualsiasi tipo di sistema operativo Microsoft per l'invio di messaggi di posta elettronica via pagine web in ASP. Esso infatti, a differenza di CDONTS (l'oggetto predefinito della Microsoft per l'invio di email via pagine asp), non ha bisogno di un server virtuale SMTP installato sulla stessa macchina server che gestisce il sito web.
Infatti, una delle proprietà di questo oggetto, è la proprietà HOST che deve essere impostata con il nome del server SMTP da utilizzare come gateway per l'inoltro delle email.
Come detto in precedenza, è possibile utilizzare PERSITS ASPEMAIL sia su Windows 98/ME con Personal Web Server e sia su Windows NT/2000 con Internet Information Services 4/5.0.
E' inoltre possibile, oltre a poter configurare il formato della e-mail sia come testo che come HTML, allegare degli attachment che verranno gestiti dal componente DEMOWARE Trial PERSITS UPLOAD (che non analizzeremo in questa guida essenziale).

Attenzione però: se decidete di pubblicare le vostre pagine asp che utilizzano l'oggetto ASPEmail su qualche server remoto (fornitore di spazio web su internet) dovete essere certi che quel server supporti il componente ASPEmail, in quanto, non essendo un componente built-in di ASP, è possibile che esso non sia installato sul server.

Per scaricare l'oggetto cliccate qui.

Come configurare lo script

Vediamo un primo esempio di utilizzo con uno script che non fa uso di variabili nel settaggio dei parametri dell'oggetto:

<%
Dim objMail

'Creiamo l'oggetto
Set objMail = Server.CreateObject("Persits.MailSender")

'Specifichiamo il server SMTP da utilizzare.
'Se si tratta del vostro PC domestico
'mettete quello del vostro Internet Provider
'ovvero quello che specificate nel programma
'per l'invio della posta elettronica
objMail.Host = "smtp.provider.com"

'Indirizzo email del mittente
objMail.From = "pippo@topolinia.com"

'Una voce opzionale è quella relativa al nome
'del mittente da specificare nel seguente modo
objMail.FromName = "Pippo Da Topolinia"

'specifichiamo adesso l'indirizzo del destinatario
'e se vogliamo anche il suo nome
objMail.AddAddress "paperino@paperopoli.com", "Paperino Paolino"

'Adesso tocca all'oggetto della mail
objMail.Subject = "Saluti da Topolinia!"

'Il contenuto della mail in formato testo
objMail.Body = "Ciao Paperino, come va da quelle parti?" & chr(10) &_
"Salutami tuo zio Paperone!" & chr(10) &_
"A presto, Pippo."

'Adesso facciamo in modo che se nell'invio della mail
'si verifica un errore lo script andrà avanti senza interrompersi
On Error Resume Next

'Inviamo la mail
objMail.Send

'puliamo la memoria allocata dall'oggetto
Set objMail = Nothing

'Effettuaimo un controllo su eventuali errori
'verificatisi durante l'invio della mail
If Err.Number <> 0 Then
Response.Write "Si è verificato un errore: " & Err.Description
Else
Response.Write "Email inviata con successo!"
End If

%>

Esaminando lo script possiamo notare che la mail è stata trattata come semplice testo.
E' comunque possibile inviare una email in formato HTML.
Sostituiamo la parte relativa a objMail.Body con questa:

<%
objMail.Body = "<html><head><title>Email</title>" &_
"</head><body bgcolor=white>" &_
"" &_
"Ciao Paperino, come va da quelle parti?" &_
"Salutami tuo zio Paperone! " &_
"A presto, Pippo.</body></html>"

'Specifichiamo il formato mail in HTML
objMail.IsHTML = True
%>

Per integrare all'interno del corpo mail in HTML delle variabili, la tecnica da seguire è la stessa utilizzata per i Response.Write misti con HTML (e testo fisso) con variabili.

<%
objMail.Body = "Ciao sono " & Request.Form("From") &_
", come va?"
objMail.IsHTML = True
%>

Come inserire delle variabili all'interno script

Per poter inserire delle variabili all'interno dello script attenersi a questo esempio (consideriamo il caso di dati passati allo script tramite FORM):

<%
objMail.From = "" & Request.Form("From") & ""

objMail.FromName = "" & Request.Form("FromName") & ""

objMail.AddAddress "" & Request.Form("To") & "", "" &_
Request.Form("ToName") & ""

objMail.Subject = "" & Request.Form("Subject") & ""

objMail.Body = Request.Form("Body")
%>

Altre paricolarità

Oltre a ObjMail.AddAddress è possibile specificare il campo CC (per conoscenza o Carbon Copy) in questo modo:

<%
objMail.AddCC "paperone@paperopoli.com"
' oppure (con le variabili)
objMail.AddCC "" & Request.Form("CC") &""
%>

Un'altra funzione che il componente è in grado di svolgere è quella dell'invio di mail ai newsgroup. Per far ciò bisogna impostare come HOST il server delle news da noi utilizzato in questo modo:

<%
objMail.Host = "news.dominio.com"
%>

Infine per l'invio della mail alla news bisogna impostare la proprietà SendToNewsgroup, seguita dal titolo del newsgroup, al posto del classico objMail.Send:

<%
objMail.SendToNewsgroup "dominio.tema.com"
%>

Si ringrazia OscarJSWeb.com per la gentile concessione dell'articolo.

Vota questo articolo >>

AspIn.com

Utilità

Segnala questa pagina ad un amico

Versione stampabile di questa pagina

Link

software ecommerce


	Utenti connessi: 111		Home \| Forum \| Tutorials \| Articoli \| Tips&Tricks \| Scripts \| Store \| Hosting \| E-Corsi \| Libri