<%@ Language= "VBScript"%>
<%
' Imponiamo la dichiarazione esplicita delle variabili
Option Explicit

' Funzione che restituisce lo spazio residuo di una determinata unità disco
Function DiskFreeSpace(sDiskDrive)

  ' Creiamo l'oggetto FileSystemObject
  Dim objFSO
  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

  ' Impostiamo l'unità da controllare
  Dim DiskDrive
  Set DiskDrive = objFSO.GetDrive(sDiskDrive)

  ' Ricaviamo lo spazio residuo in Kbyte
  Dim iFreeSpace
  iFreeSpace = DiskDrive.FreeSpace

  ' Trasformiamo il residuo in Kbyte
  iFreeSpace = iFreeSpace / 1024
  ' Eliminiamo la parte decimale
  iFreeSpace = FormatNumber(iFreeSpace, 0)

  ' Ricaviamo lo spazio totale in Kbyte
  Dim iTotalSize
  iTotalSize = DiskDrive.TotalSize

  ' Trasformiamo lo spazio totale in Kbyte
  iTotalSize = iTotalSize / 1024
  ' Eliminiamo la parte decimale
  iTotalSize = FormatNumber(iTotalSize, 0)

  ' Restituiamo il risultato
  DiskFreeSpace = iFreeSpace & "Kb residui su " & iTotalSize & "Kb totali."

  ' Liberiamo la memoria
  Set DiskDrive = Nothing
  Set objFSO = Nothing

End Function

' Impostiamo l'unità da controllare
Dim sDriveLetter
sDriveLetter = "c"

' Visualizziamo il risultato richiamando la funzione DiskFreeSpace
' a cui passiamo l'unità da controllare
Response.Write "Unità " & sDriveLetter & ": " & DiskFreeSpace(sDriveLetter)
%>